@echo off
setlocal

REM ============================================================
REM  deepwork web console. Drag and drop a project folder onto
REM  this file: DeepSeek gets tools (NEED / LIST / FIND) and can
REM  read that folder himself, step by step.
REM  Needs the deepseek-api service running (its own start.cmd).
REM  ASCII only on purpose - cmd.exe mangles UTF-8 Cyrillic.
REM ============================================================

echo ========================================
echo    deepwork - DeepSeek with tools
echo ========================================
echo.

REM %~dp0 ALWAYS ends with a backslash. A bare "%VAR%" argument built from it
REM would escape its own closing quote - that bug already ate a flag once in
REM ollama_orchestro. Keep the trimmed copy for whole-path arguments.
set "DW_DIR=%~dp0"
set "DW_ROOT=%DW_DIR:~0,-1%"

if "%~1"=="" (
    echo [ERROR] No project folder specified!
    echo Drag and drop a project folder onto this file.
    echo.
    pause
    exit /b 1
)
if not exist "%~1" (
    echo [ERROR] Folder "%~1" does not exist!
    echo.
    pause
    exit /b 1
)
echo [OK] Project folder: %~1

where node >nul 2>&1
if errorlevel 1 (
    echo [ERROR] Node.js not found in PATH!
    echo.
    pause
    exit /b 1
)
echo [OK] Node.js found

powershell -NoProfile -Command "try { Invoke-RestMethod -Uri 'http://localhost:11500/api/tags' -TimeoutSec 3 | Out-Null; exit 0 } catch { exit 1 }" >nul 2>&1
if errorlevel 1 (
    echo [WARN] deepseek-api is NOT ready on port 11500.
    echo        Run start.cmd in the deepseek-api folder - it starts the
    echo        browser by itself. Log in to DeepSeek in the window it opens.
    echo        The console will start anyway and show the same warning.
    echo.
)

cd /d "%~1"

echo.
echo Open the printed address in your DEFAULT browser, not the one
echo that deepseek-api drives.
echo Ctrl+C here stops it.
echo.
node "%DW_DIR%deepwork.mjs" ui

echo.
pause